Sie können dies auch in Outlook über VBA tun. In Office 2010 können Sie nicht mehr über die meisten dieser Lösungen entfernen.
Word, PowerPoint und Excel erlauben Ihnen die Verwendung dieser einfachen Lösung .
Outlook erfordert mehr Aufwand, da es sowohl den Explorer als auch den Inspector verwendet, die in unterschiedlichen Kontexten beide diese Befehlsleiste aktiviert haben. Die Lösung ist daher zweiteilig.
Teil eins ist das Einrichten von WithEvents für die Erstellung jedes neuen Inspektors. Im Allgemeinen werden diese immer dann erstellt/zerstört, wenn Sie eine Nachricht/Ereignis/etc. öffnen. Selbst wenn Sie also jeden aktuellen Inspektor treffen, wird die Befehlsleiste bei den neuen Inspektoren nicht deaktiviert sein.
Geben Sie in Ihrem VBA-Editor (Alt+F11) Folgendes in ThisOutlookSession ein. Jeder neue Inspektor (und auch Explorer, obwohl ich noch keinen Explorer erstellt habe) wird seine Befehlsleiste deaktiviert haben.
Public WithEvents colInspectors As Outlook.Inspectors
Public WithEvents objInspector As Outlook.Inspector
Public WithEvents colExplorers As Outlook.Explorers
Public WithEvents objExplorer As Outlook.Explorer
Public Sub Application_Startup()
Init_colExplorersEvent
Init_colInspectorsEvent
End Sub
Private Sub Init_colExplorersEvent()
Set colExplorers = Outlook.Explorers
End Sub
Private Sub Init_colInspectorsEvent()
'Initialize the inspectors events handler
Set colInspectors = Outlook.Inspectors
End Sub
Private Sub colInspectors_NewInspector(ByVal NewInspector As Inspector)
Debug.Print "new inspector"
NewInspector.commandbars("Research").Enabled = False
'This is the code that creates a new inspector with events activated
Set objInspector = NewInspector
End Sub
Private Sub colExplorers_NewExplorer(ByVal NewExplorer As Explorer)
'I don't believe this is required for explorers as I do not think Outlook
'ever creates additional explorers... but who knows
Debug.Print "new explorer"
NewExplorer.commandbars("Research").Enabled = False
'This is the code that creates a new inspector with events activated
Set objExplorer = NewExplorer
End Sub
Dies führt jedoch nur dazu, dass das Menü aus einigen der Ansichten in Outlook verschwindet. Sie müssen immer noch das folgende Makro ausführen, um es aus allen Explorern zu entfernen. Soweit ich das beurteilen kann, bleibt es bestehen, wenn Sie Outlook schließen/öffnen:
Private Sub removeOutlookResearchBar()
'remove from main Outlook explorer
Dim mExp As Explorer
For Each mExp In Outlook.Explorers
mExp.commandbars("Research").Enabled = False
Next mExp
End Sub
