Wie kann ich nach einer frischen Windows-Installation - XP oder 7 - Windows-Updates “erzwingen”?
Ich möchte nicht nach einer Woche “alte” Windows-Updates haben, könnte man das also in “einem Schritt” erledigen? Gibt es irgendwelche “magischen” Befehle, die Windows dazu zwingen, nach Updates zu suchen, und wenn es welche gibt, diese zu installieren?
Über den üblichen Weg der Verwendung von Windows Update hinaus können Sie eine Prüfung über eine Befehlszeile erzwingen.
Öffnen Sie eine Administrator-Eingabeaufforderung und führen Sie aus:
C:\> %windir%\system32\wuauclt.exe /detectnow
Wuauclt.exe ist der AutoUpdate-Client von Windows Update und wird verwendet, um nach verfügbaren Updates (für die verschiedenen Versionen der MS Windows-Plattform) von Microsoft Update zu suchen.
Damit wird keine Installation erzwungen.
Sie können mithilfe eines Skripts automatisch nach Updates suchen und diese installieren. Dies funktioniert sowohl unter XP als auch unter Windows 7.
Es gibt eine Reihe von Skripten zum Herunterladen, hier ist meins :
' Written in 2007 by Harry Johnston, University of Waikato, New Zealand.
' This code has been placed in the public domain. It may be freely
' used, modified, and distributed. However it is provided with no
' warranty, either express or implied.
'
' Exit Codes:
' 0 = scripting failure
' 1 = error obtaining or installing updates
' 2 = installation successful, no further updates to install
' 3 = reboot needed; rerun script after reboot
'
' Note that exit code 0 has to indicate failure because that is what
' is returned if a scripting error is raised.
'
Set updateSession = CreateObject("Microsoft.Update.Session")
Set updateSearcher = updateSession.CreateUpdateSearcher()
Set updateDownloader = updateSession.CreateUpdateDownloader()
Set updateInstaller = updateSession.CreateUpdateInstaller()
Do
WScript.Echo
WScript.Echo "Searching for approved updates ..."
WScript.Echo
Set updateSearch = updateSearcher.Search("IsInstalled=0")
If updateSearch.ResultCode <> 2 Then
WScript.Echo "Search failed with result code", updateSearch.ResultCode
WScript.Quit 1
End If
If updateSearch.Updates.Count = 0 Then
WScript.Echo "There are no updates to install."
WScript.Quit 2
End If
Set updateList = updateSearch.Updates
For I = 0 to updateSearch.Updates.Count - 1
Set update = updateList.Item(I)
WScript.Echo "Update found:", update.Title
Next
WScript.Echo
updateDownloader.Updates = updateList
updateDownloader.Priority = 3
Set downloadResult = updateDownloader.Download()
If downloadResult.ResultCode <> 2 Then
WScript.Echo "Download failed with result code", downloadResult.ResultCode
WScript.Echo
WScript.Quit 1
End If
WScript.Echo "Download complete. Installing updates ..."
WScript.Echo
updateInstaller.Updates = updateList
Set installationResult = updateInstaller.Install()
If installationResult.ResultCode <> 2 Then
WScript.Echo "Installation failed with result code", installationResult.ResultCode
For I = 0 to updateList.Count - 1
Set updateInstallationResult = installationResult.GetUpdateResult(I)
WScript.Echo "Result for " & updateList.Item(I).Title & " is " & installationResult.GetUpdateResult(I).ResultCode
Next
WScript.Quit 1
End If
If installationResult.RebootRequired Then
WScript.Echo "The system must be rebooted to complete installation."
WScript.Quit 3
End If
WScript.Echo "Installation complete."
Loop
Sie führen es von der Kommandozeile wie folgt aus:
cscript wsusupdate.vbs
Mein Skript ist nur minimal funktional, kann aber trotzdem nützlich sein. Es gibt andere solche Skripte mit vielen zusätzlichen Funktionen, versuchen Sie eine Google-Suche.
Eine andere Möglichkeit, eine echte erneute Suche nach Updates zu erzwingen, ist das Löschen aller Updates, die in %windir%\Windows\SoftwareDistribution\Download gespeichert sind:
NET STOP wuauserv
RD /S /Q %windir%\SoftwareDistribution\Download
NET START wuauserv
Dann gehen Sie zu Windows Update und “Nach Updates suchen”. Es kann eine Stunde dauern, da jede aktualisierbare Datei auf Ihrem Systemvolume überprüft wird (nachfolgende “Überprüfungen auf Updates” sind schnell). Dieser Ansatz eliminiert Fehler, verpfuschte Updates und liefert ein sauberes, aktuelles System, zumindest soweit MS es sieht.
ich verwende ein zweites tool namens wuinstall für die aktualisierung einer frischen windows-installation. damit kann man den gesamten aktualisierungsprozess automatisieren, einschließlich automatischer neustarts. ich denke, es ist eine der schnellsten möglichkeiten, ein frisches windows auf den neuesten stand zu bringen, ohne dass der benutzer sich darum kümmern muss.
Ich habe festgestellt, dass Windows Update eine Fehlermeldung ausgibt, wenn Sie bei der Neuinstallation von Windows 7 den IE aktualisiert haben oder wenn Sie den IE noch nicht gestartet und die Einführungsfragen beantwortet haben. Ich habe auch keine Möglichkeit gefunden, Windows Update auf Microsoft Update umzuschalten, ohne über die GUI zu gehen, also starte ich den IE manuell, initialisiere ihn und richte dann Windows Update über die GUI ein, damit ich auf Microsoft Update umschalten und den anfänglichen Fehler vermeiden kann. Ihre Erfahrungen können variieren.